Gert  Van den Eynde <gvd### [at] hotmailcom> wrote:
> could someone provide me with a small example that shows the effect of the
> eccentricity parameter (going from -1 to 1) in the Henyey-Greenstein
> scattering media (type 5). The effect may be (artificially) exagerated if
> needed...

  Try playing with the eccentricity value in this scene to see how it
affects the media. The scene contains light coming from the front and from
the behind to illustrate the difference.


media
{ scattering { 5, .1 extinction .1 eccentricity .4 }
}

camera { location <-9, 0, -2> look_at <0, -1, 0> angle 65 }
light_source { <5, 3, -9>, .3 media_interaction off shadowless }
light_source
{ <7, 3.5, 4>, 1
  spotlight point_at <3, 0, 4> radius 18 falloff 19
}
light_source
{ <-7, 3.5, -4>, 1
  spotlight point_at <0, 0, -4> radius 18 falloff 19
}

box
{ <-10, -4, -10>, <10, 4, 10> inverse
  pigment { checker rgb 1, rgb .5 }
}

#declare Object =
  union
  { cylinder { 0, y*2.5, .3 }
    torus { 1, .3 rotate z*90 translate y*3.5 }
    pigment { rgb <1, .5, 0> }
  }

object { Object translate <1, -4, 4> }
object { Object translate <1, -4, -4> }

Post a reply to this message